#
# .login - csh login script, read by login shell, after `.cshrc' at login.
#
# see also csh(1), environ(7).
#

setenv TZ /usr/share/zoneinfo/Europe/Dublin

if ($?TMUX) then
	setenv TERM screen-256color
else if ($tty =~ ttyv*) then
	setenv TERM cons25
else
	setenv TERM xterm-256color
endif

# Completions grabbed from various places.
complete cd      'p/1/d/'
complete rmdir   'p/1/d/'
complete fg      'c/%/j/'
complete man     'C/*/c/'
complete service 'c/-/(e l r v)/' 'p/1/`service -l`/' 'n/*/(start stop reload restart status rcvar onestart onestop)/'
complete tmux    'n/*/(attach detach has kill-server kill-session lsc lscm ls lockc locks new refresh rename showmsgs source start suspendc switchc)/'
complete make    'n@*@`make -pn | sed -n -E "/^[#_.\/[:blank:]]+/d; /=/d; s/[[:blank:]]*:.*//gp;"`@'
complete pkill   'c/-/S/' 'n/*/`ps -axc -o command="" | sort -u`/'
complete sudo    'n/-l/u/' 'p/1/c/'
complete chgrp   'p/1/g/'
complete chown   'c/*[.:]/g/' 'p/1/u/:' 'n/*/f/'

complete git 'p/1/(add merge-recursive add--interactive merge-resolve am \
	merge-subtree annotate merge-tree apply mergetool archimport mktag \
	archive mktree bisect mv bisect--helper name-rev blame notes branch \
	pack-objects bundle pack-redundant cat-file pack-refs check-attr \
	patch-id check-ref-format peek-remote checkout prune checkout-index \
	prune-packed cherry pull cherry-pick push clean quiltimport clone \
	read-tree column rebase commit receive-pack commit-tree reflog config \
	relink count-objects remote credential-cache remote-ext \
	credential-cache--daemon remote-fd credential-store remote-ftp daemon \
	remote-ftps describe remote-http diff remote-https diff-files \
	remote-testgit diff-index repack diff-tree replace difftool \
	repo-config difftool--helper request-pull fast-export rerere \
	fast-import reset fetch rev-list fetch-pack rev-parse filter-branch \
	revert fmt-merge-msg rm for-each-ref send-email format-patch send-pack \
	fsck sh-i18n--envsubst fsck-objects shell gc shortlog \
	get-tar-commit-id show grep show-branch hash-object show-index help \
	show-ref http-backend stage http-fetch stash http-push status \
	imap-send stripspace index-pack submodule init symbolic-ref init-db \
	tag instaweb tar-tree log unpack-file lost-found unpack-objects \
	ls-files update-index ls-remote update-ref ls-tree update-server-info \
	mailinfo upload-archive mailsplit upload-pack merge var merge-base \
	verify-pack merge-file verify-tag merge-index web--browse \
	merge-octopus whatchanged merge-one-file write-tree merge-ours)/' \
	'n@checkout@`git branch -a | sed -r "s|^[\* ]+(remotes/origin/)?||; /^HEAD/d" | sort -u`@' \
	'n@co@`git branch -a | sed -r "s|^[\* ]+(remotes/origin/)?||; /^HEAD/d" | sort -u`@' \
	'n@branch@`git branch -a | sed -r "s|^[\* ]+(remotes/origin/)?||; /^HEAD/d" | sort -u`@'

complete find 'n/-fstype/"(nfs 4.2)"/' 'n/-name/f/' \
	'n/-type/(c b d f p l s)/' \
	'n/-user/u/ n/-group/g/' \
	'n/-exec/c/' 'n/-ok/c/' \
	'n/-cpio/f/' \
	'n/-ncpio/f/' \
	'n/-newer/f/' \
	'c/-/(fstype name perm prune type user nouser group nogroup size inum \
		atime mtime ctime exec ok print ls cpio ncpio newer xdev depth \
		daystart follow maxdepth mindepth noleaf version anewer cnewer \
		amin cmin mmin true false uid gid ilname iname ipath iregex \
		links lname empty path regex used xtype fprint fprint0 fprintf \
		print0 printf not a and o or)/' \
	'n/*/d/'