menologion/quickshell/shell.qml

//@ pragma UseQApplication

import QtQuick
import QtQuick.Layouts
import Quickshell
import Quickshell.Wayland
import qs
import qs.modules
import qs.services

// A runnable widget on its own — `quickshell -p quickshell/shell.qml`.
//
// It sits on the background layer, so it behaves like part of the wallpaper:
// always under your windows, never stealing a click. Drop the Horologion
// component into an existing shell instead if you already have one.
ShellRoot {
    Variants {
        model: Quickshell.screens

        PanelWindow {
            required property var modelData
            screen: modelData

            WlrLayershell.layer: WlrLayer.Background
            WlrLayershell.namespace: "horologion"
            exclusionMode: ExclusionMode.Ignore
            color: "transparent"

            anchors { top: true; right: true }
            margins { top: 24; right: 24 }

            implicitWidth: Config.width
            implicitHeight: content.implicitHeight

            ColumnLayout {
                id: content
                anchors.fill: parent

                Horologion {
                    // Leave empty to follow `typikon --set-default`, or name a
                    // jurisdiction here: "rocor", "antiochian", "oca", ...
                    Component.onCompleted: Typikon.jurisdiction = ""
                }
            }
        }
    }
}